Arduino IDE(Wire.endTransmission関数の使い方)

Wite.endTransmission関数

Wite.endTransmission関数はI2C※1通信時におけるスレーブ※2デバイスに対しての送信処理を完了します。

つまりキュー※3に保持されたデータを、endTransmission()関数で送信します。

使用例

Arduino IDEで使用するWite.beginTransmission関数の使用例は以下の通りです。

試しにこのプログラムをArduinoUNOで実行するとセンサー(電子コンパスモジュール)で測定した値をArduinoに取得し、その値から計算された方位がPCのシリアルモニタ上に表示されます。

#include <Wire.h> //I2C Arduino Library
#define address 0x1E //0011110b, I2C 7bit address of HMC5883

void setup() {
  //GY-273
  Serial.begin(9600);
  Wire.begin();
  Wire.beginTransmission(address); //open communication with HMC5883
  Wire.write(0x02); //select mode register
  Wire.write(0x00); //continuous measurement mode
  Wire.endTransmission();
}

void loop() {
  Serial.println(Angleread()) ;          // 方位角を返す
  delay(500) ;                            // 500ms後に繰り返す
}
int Angleread() {
  int x, y, z; //triple axis data
  Wire.beginTransmission(address);
  Wire.write(0x03); //select register 3, X MSB register
  Wire.endTransmission();
  Wire.requestFrom(address, 6);
  if (6 <= Wire.available()) {
    x = Wire.read() << 8; //X msb
    x |= Wire.read(); //X lsb
    z = Wire.read() << 8; //Z msb
    z |= Wire.read(); //Z lsb
    y = Wire.read() << 8; //Y msb
    y |= Wire.read(); //Y lsb
  }
  return atan2((x + 20) , (y + 20) * (-1)) * RAD_TO_DEG + 180; //40と20は補正値
}

図1：プログラム例

※ArduinoIDEリファレンス

Wire.endTransmission(stop)関数の【パラメータ】を表1に、【戻り値】を表2に示します。

表1：Wire.endTransmission(stop)関数の【パラメータ】
項目	内容
stop (省略可)	trueに設定するとstopメッセージをリクエストのあと送信し、I2Cバスを開放します(デフォルト)。falseに設定するとrestartメッセージをリクエストのあと送信し、コネクションを維持します。

表2：Wire.endTransmission(stop)関数の【戻り値】
項目	内容
0	成功
1	送ろうとしたデータが送信バッファのサイズを超えた
2	スレーブ・アドレスを送信し、NACKを受信した
3	データ・バイトを送信し、NACKを受信した
4	その他のエラー